home *** CD-ROM | disk | FTP | other *** search
/ ETO Development Tools 1 / ETO Development Tools 1.iso / Essentials / Developer Essentials Jul 90 / Apple II / Imaging / ProDOS IW Toolkit / STARTUP.bas < prev    next >
Encoding:
BASIC Source File  |  1984-03-08  |  6.9 KB  |  193 lines
  1. 10  GOTO 50000
  2. 20 :
  3. 25  FOR I = 1 TO 40: PRINT "-";: NEXT 
  4. 29  RETURN 
  5. 30 :
  6. 33  & "WINDOW",22,24: HOME 
  7. 35  & "GOTOYX",22,1;"ENTER A NUMERIC SELECTION, OR USE THE": PRINT "ARROW AND RETURN KEYS"
  8. 39  RETURN 
  9. 40 :
  10. 45  & "WINDOW",22,24: HOME : & "GOTOYX",22,1;"CTRL S - TO PAUSE, CTRL C - TO STOP": PRINT "CATALOG LISTING": & "WINDOW"4,20: RETURN 
  11. 50 :
  12. 60  TEXT : HOME : PRINT "IMAGEWRITER TOOL KIT": & "JUSTIFY","VERSION 1.5",R,40: & "GOTOYX",2,1;"COPR 1984 APPLE COMPUTER"
  13. 70  & "GOTOYX",3,1: GOSUB 20: & "GOTOYX",21,1: GOSUB 20
  14. 77  & "WINDOW",4,20
  15. 79  RETURN 
  16. 80 :
  17. 85  & "WINDOW",22,24: HOME 
  18. 90  PRINT "CTRL X - TO CLEAR, RETURN - TO ACCEPT": PRINT "DELETE OR CTRL D - DELETE CHARACTER": PRINT "ESC - RETURN TO SELECT IMAGE MENU";
  19. 95  & "WINDOW",4,20
  20. 99  RETURN 
  21. 100 :
  22. 105 ESCFLG% = 0
  23. 110  & "GOTOYX",Y +I,10: INVERSE : PRINT MENU$(ME%,I): NORMAL 
  24. 120  & "KBD",X$
  25. 130 X =  VAL(X$): IF X >0  AND X <MCOUNT +1  THEN  GOSUB 180: GOTO 120
  26. 140  IF X$ =  CHR$(10)  OR X$ =  CHR$(21)  THEN  & "GOTOYX",Y +I,10: PRINT MENU$(ME%,I):I = I +1: IF I = MCOUNT +1  THEN I = 1: GOTO 110
  27. 150  IF X$ =  CHR$(11)  OR X$ =  CHR$(8)  THEN  & "GOTOYX",Y +I,10: PRINT MENU$(ME%,I):I = I -1: IF I = 0  THEN I = MCOUNT: GOTO 110
  28. 160  IF X$ =  CHR$(13)  THEN X = I: GOSUB 180: RETURN 
  29. 165  IF X$ =  CHR$(27)  THEN ESCFLG% = 1: RETURN 
  30. 170  GOTO 110
  31. 180  & "GOTOYX",I +Y,10: PRINT MENU$(ME%,I):I = X: INVERSE : & "GOTOYX",Y +I,10: PRINT MENU$(ME%,I): NORMAL : RETURN 
  32. 200  & "WINDOW",22,24: HOME 
  33. 210  PRINT  CHR$(7);"INSERT THE IMAGEWRITER TOOL KIT DISK": PRINT "INTO DRIVE 1 AND PRESS THE RETURN KEY": PRINT "ESC - ";ESC$;
  34. 220  RETURN 
  35. 300 :
  36. 310  & "WINDOW",4,20: HOME 
  37. 320 Y = 8:MCOUNT =  VAL(MENU$(ME%,0))
  38. 330  FOR I = 1 TO MCOUNT: & "GOTOYX",Y +I,6: PRINT I;" - ";MENU$(ME%,I)
  39. 340  NEXT 
  40. 350  RETURN 
  41. 500  TEXT : & "WINDOW",22,24: HOME : PRINT  CHR$(7);"INTERFACE CARD COULD NOT BE IDENTIFIED": PRINT "ESC - RETURN TO MAIN MENU"
  42. 510  & "KBD",X$
  43. 520  IF X$ =  CHR$(27)  THEN 1000
  44. 530  GOTO 510
  45. 550  & "KBD",X$:
  46. 600  IF X$ =  CHR$(27)  THEN 1000
  47. 1000 :
  48. 1002  GOSUB 30
  49. 1003 ME% = 0: GOSUB 300: REM  PRINT MENU
  50. 1005  & "GOTOYX",5,1: & "JUSTIFY","MAIN MENU",C
  51. 1025  & "GOTOYX",23,1: PRINT  CHR$(29);
  52. 1030 I = 1
  53. 1033  GOSUB 100
  54. 1035  IF ESCFLG%  THEN 1033
  55. 1040  ON X GOTO 2000,3000,4000,5000,6000,7000
  56. 2000 :
  57. 2005 ME% = 1: GOSUB 300
  58. 2010  & "GOTOYX",5,1: & "JUSTIFY","SELECT GRAPHIC IMAGE",C
  59. 2043  GOSUB 30: REM  Print Selection Message
  60. 2045  & "GOTOYX",24,1: PRINT "ESC - RETURN TO MAIN MENU";
  61. 2050 I = 1
  62. 2060  GOSUB 100
  63. 2070  IF ESCFLG%  THEN 1000
  64. 2080  ON X GOTO 2100,2300,2500,2700,2700,2700,2700,2700
  65. 2100  GOSUB 40
  66. 2110  & "WINDOW",4,20: HOME : PRINT  CHR$(4);"CAT": PRINT 
  67. 2116 DF$ = ""
  68. 2120  GOSUB 80
  69. 2200  & "GOTOYX",20,1;"ENTER FILENAME:";: & "READ",20,17,DF$,2000,15
  70. 2210  IF DF$ = ""  THEN 2000
  71. 2215  & "GOTOYX",20,17: & "JUSTIFY",DF$,L,15;
  72. 2220  PRINT  CHR$(4);"BLOAD";DF$;",A$2000"
  73. 2230  GOTO 1000
  74. 2300 :
  75. 2310 ME% = 2: GOSUB 300
  76. 2320  & "GOTOYX",5,1: & "JUSTIFY","SET PRODOS PREFIX",C
  77. 2345  & "GOTOYX",24,1: PRINT "ESC - ";RS$;
  78. 2350 I = 1
  79. 2360  GOSUB 100
  80. 2370  IF ESCFLG%  THEN 2000
  81. 2380  ON X GOTO 2400,2400,2450
  82. 2400  PRINT  CHR$(4);"PREFIX,D";X
  83. 2410  GOTO 2000
  84. 2450 DF$ = ""
  85. 2455  GOSUB 80
  86. 2460  & "GOTOYX",18,1: PRINT : PRINT "ENTER PATHNAME:";: & "READ",19,17,DF$,2000,63
  87. 2463  IF DF$ = ""  THEN 2000
  88. 2465  & "GOTOYX",19,17: & "JUSTIFY",DF$,L,63;
  89. 2470  PRINT  CHR$(4);"PREFIX";DF$
  90. 2480  GOTO 2000
  91. 2500 :
  92. 2510  GOSUB 40
  93. 2530 : & "WINDOW",4,20: HOME : PRINT  CHR$(4);"CAT"
  94. 2540  & "WINDOW",22,24: HOME 
  95. 2550  & "GOTOYX",22,1: PRINT "ESC - RETURN TO SELECT IMAGE MENU";
  96. 2560  & "KBD",X$
  97. 2570  IF X$ =  CHR$(27)  THEN 2000
  98. 2580  GOTO 2560
  99. 2700 :
  100. 2720  PRINT  CHR$(4);"bload";FL$(X -4)
  101. 2730  GOTO 1000
  102. 3000 :
  103. 3010  POKE 49239,0: POKE 49235,0: POKE 49232,0: POKE 49236,0
  104. 3020  & "WINDOW",22,24: HOME : PRINT "PRESS RETURN TO SEE THE FULL SCREEN": PRINT "ESC - RETURN TO MAIN MENU";
  105. 3100  & "KBD",X$
  106. 3120  IF X$ =  CHR$(27)  THEN  TEXT : GOSUB 50: GOTO 1000
  107. 3130  IF X$ =  CHR$(13)  THEN  POKE 49234,0: GOTO 3100
  108. 3200  GOTO 3100
  109. 4000 :
  110. 4005 ME% = 3: GOSUB 300
  111. 4010  & "GOTOYX",5,1: & "JUSTIFY","CHANGE PRINT OPTIONS",C
  112. 4025  GOSUB 30
  113. 4027  & "GOTOYX",24,1: PRINT "ESC - RETURN TO MAIN MENU";
  114. 4030 I = XFROPT +1
  115. 4032  IF  PEEK(64448) = 234  THEN  & "GOTOYX",20,2;"PRINTER CARD IN SLOT: ";PS;
  116. 4033  GOSUB 100
  117. 4035  IF ESCFLG% = 1  THEN 1000
  118. 4040  ON X GOTO 4100,4100,4100,4100,4200
  119. 4100 XFROPT = X -1
  120. 4110  GOTO 1000
  121. 4200 :
  122. 4210 X$ =  STR$(PS)
  123. 4220  & "WINDOW",22,24: HOME : PRINT "ENTER THE SLOT NUMBER WHERE THE PRINTER": PRINT "CARD IS INSTALLED,  ESC - RETURN TO ": PRINT "CHANGE PRINT OPTIONS MENU";
  124. 4230  & "READ",20,24,X$,4000,1
  125. 4240 PS =  VAL(X$)
  126. 4250  PRINT  CHR$(4);"STORE KIT.VAR"
  127. 4260  GOTO 4000
  128. 5000 :
  129. 5010  PRINT  CHR$(13)
  130. 5020  PRINT  CHR$(4);"PR#";PS
  131. 5030  POKE 49239,0: POKE 49234,0: POKE 49232,0: POKE 49236,0
  132. 5040  & "GRAF",PSLOT,XFROPT
  133. 5045  PRINT  CHR$(4);"PR#0"
  134. 5050  IF  PEEK(252) = 255  THEN 500
  135. 5060  TEXT : GOSUB 50: GOTO 1000
  136. 6000 :
  137. 6030  PRINT  CHR$(4);"BLOAD SUBSCRIPT.FONT, A$2000"
  138. 6033  INVERSE 
  139. 6035  & "GOTOYX",20,2;"DOWNLOADING SUBSCRIPT/SUPERSCRIPT FONT";
  140. 6037  NORMAL 
  141. 6039  PRINT  CHR$(4);"PR#";PS
  142. 6040  & "DOWNLOAD",PSLOT,XFROPT
  143. 6045  PRINT  CHR$(4);"PR#0"
  144. 6050  IF  PEEK(252) = 255  THEN : & "WINDOW",18,20: HOME : GOTO 500
  145. 6060  GOTO 1000
  146. 7000  & "WINDOW",22,24: HOME 
  147. 7003  PRINT  CHR$(7)
  148. 7005  & "GOTOYX",22,1: & "JUSTIFY","ARE YOU SURE? (Y/N)",C,39
  149. 7010  & "KBD",X$
  150. 7020  IF X$ = "Y"  THEN 7100
  151. 7030  IF X$ =  CHR$(27)  THEN 1000
  152. 7080  IF X$ = "N"  THEN 1000
  153. 7090  GOTO 7010
  154. 7100  TEXT 
  155. 7105  FOR I = 0 TO 15: READ A: POKE 768 +I,A: NEXT 
  156. 7110  CALL 768
  157. 7120  DATA  32,0,191,101,10,03,0,0,0,0,4,0,0,0,0,0
  158. 40000  & "ERR",EC,EL:ESC$ = "RETURN TO MAIN MENU":BRANCH = 1000
  159. 40003  IF EL =  -24526  THEN 42000
  160. 40005  IF EC = 255  AND EL = 2110  THEN 2120
  161. 40007  IF EC = 255  AND EL = 2530  THEN 2540
  162. 40010  IF EC = 255  THEN  RESUME 
  163. 40015  IF EL = 2470  THEN ESC$ = RP$:BRANCH = 2455
  164. 40020  IF EL = 6030  THEN 41000
  165. 40023  IF EL = 2720  THEN ESC$ = RS$:BRANCH = 2000: GOTO 41000
  166. 40025  IF EL = 2220  THEN ESC$ = RF$:BRANCH = 2120
  167. 40027  IF EL = 4250  THEN ESC$ = ROM$:BRANCH = 4000: GOTO 41000
  168. 40030  & "WINDOW",22,24: HOME 
  169. 40040  & "ERRMSG",EC
  170. 40050  PRINT "RETURN - TO TRY AGAIN": PRINT "ESC - ";ESC$;
  171. 40060  & "KBD",X$
  172. 40070  IF X$ =  CHR$(27)  THEN  & "GOTO",BRANCH
  173. 40080  IF X$ =  CHR$(13)  THEN  & "GOTO",EL
  174. 40090  GOTO 40060
  175. 41000 ET% = EL:T$ = ESC$:BT = BR
  176. 41010  PRINT  CHR$(4);"PREFIX";PF$: & "GOTO",EL
  177. 42000 EL = ET%:ESC$ = T$:BR = BT: GOSUB 200
  178. 42010  & "KBD",X$
  179. 42020  IF X$ =  CHR$(27)  THEN  & "GOTO",BRANCH
  180. 42030  IF X$ =  CHR$(13)  THEN  PRINT  CHR$(4);"PREFIX,D1": & "GOTO",EL
  181. 42050  GOTO 42010
  182. 50000 :
  183. 50005  CALL  PEEK(175) +256 * PEEK(176) -46
  184. 50010  & "GETBUFF": PRINT  CHR$(21)
  185. 50020  PRINT  CHR$(4);"bload graf.0": POKE 53247,00
  186. 50025  LOMEM: 16384
  187. 50030  PRINT  CHR$(4);"RESTORE KIT.VAR"
  188. 50035  GOSUB 50
  189. 50040 ::: ONERR  GOTO 40000
  190. 50043  IF  PEEK(64448) = 0  THEN MENU$(3,0) = "4":PS = 1
  191. 50045  IF  PEEK(64448) < >0  THEN MENU$(3,0) = "5"
  192. 50050  PRINT  CHR$(4);"PREFIX": INPUT PF$
  193. 50060  GOTO 1000